{
  description = "My personal desktop shell, made with Quickshell";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    systems.url = "github:nix-systems/default";

    quickshell = {
      url = "git+https://git.outfoxxed.me/outfoxxed/quickshell";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = { self, nixpkgs, systems, quickshell, ... } @ inputs:
    let
      inherit (nixpkgs) lib;
      eachSystem = lib.genAttrs (import systems);

      fonts = pkgs: with pkgs; [ material-symbols rubik nerd-fonts.jetbrains-mono ];
    in {
      packages = eachSystem (system:
        let pkgs = nixpkgs.legacyPackages.${system};
        in rec {
          quickshell-toki-night = pkgs.callPackage ./package.nix {
            quickshell = quickshell.packages.${system}.default.override {
              withX11 = false;
              withI3 = false;
            };
            fonts = fonts pkgs;
          };
          default = quickshell-toki-night;
        });

      devShells = eachSystem (system:
        let
          pkgs = nixpkgs.legacyPackages.${system};
          shell = self.packages.${system}.default;
        in {
          default = pkgs.mkShell {
            inputsFrom = [ shell ];
            packages = [ pkgs.clazy ] ++ fonts pkgs;
          };
        });
    };
}