import qs.config
import qs.custom
import qs.services
import Quickshell
import QtQuick

Item {
    id: root

    required property var uiState
    required property ShellScreen screen

    visible: width > 0
    implicitWidth: 0
    implicitHeight: content.implicitHeight

    states: State {
        name: "visible"
        when: root.uiState.osd

        PropertyChanges {
            root.implicitWidth: content.implicitWidth
        }
    }

    transitions: [
        Transition {
            from: ""
            to: "visible"

            Anim {
                target: root
                property: "implicitWidth"
                easing.bezierCurve: Config.anim.curves.expressiveDefaultSpatial
            }
        },
        Transition {
            from: "visible"
            to: ""

            Anim {
                target: root
                property: "implicitWidth"
                easing.bezierCurve: Config.anim.curves.emphasized
            }
        }
    ]

    Background {
        id: background
        visible: false
        wrapper: root
    }

    GlowEffect {
        source: background
        glowColor: Config.colors.osd
    }

    Content {
        id: content

        uiState: root.uiState
        monitor: Brightness.getMonitorForScreen(root.screen)
    }
}