import qs.config
import QtQuick
import QtQuick.Shapes

Shape {
    id: root

    required property Item wrapper
    readonly property real rounding: Config.border.rounding
    readonly property bool flatten: wrapper.height < rounding * 2
    readonly property real roundingY: flatten ? wrapper.height / 2 : rounding

    ShapePath {
        startX: (root.parent.width - root.wrapper.width) / 2 - rounding
        startY: root.parent.height + 0.5
        strokeWidth: -1
        fillColor: Config.colors.bg

        PathArc {
            relativeX: root.rounding
            relativeY: -root.roundingY
            radiusX: root.rounding
            radiusY: Math.min(root.rounding, root.wrapper.height)
            direction: PathArc.Counterclockwise
        }
        PathLine {
            relativeX: 0
            relativeY: -(root.wrapper.height - root.roundingY * 2)
        }
        PathArc {
            relativeX: root.rounding
            relativeY: -root.roundingY
            radiusX: root.rounding
            radiusY: Math.min(root.rounding, root.wrapper.height)
        }
        PathLine {
            relativeX: root.wrapper.width - root.rounding * 2
            relativeY: 0
        }
        PathArc {
            relativeX: root.rounding
            relativeY: root.roundingY
            radiusX: root.rounding
            radiusY: Math.min(root.rounding, root.wrapper.height)
        }
        PathLine {
            relativeX: 0
            relativeY: root.wrapper.height - root.roundingY * 2
        }
        PathArc {
            relativeX: root.rounding
            relativeY: root.roundingY
            radiusX: root.rounding
            radiusY: Math.min(root.rounding, root.wrapper.height)
            direction: PathArc.Counterclockwise
        }
    }

}